Məbləğləri avtomatik mətnə çevirən VBA kodu – faylı endir

Faydalı materiallar

Daha öncəki mövzuların birində, məbləğləri avtomatik yazı ilə əvəz edən kod haqqında danışarkən, bu kodun ingilis dilində olduğunu qeyd etmişdik. Əlavədəki faylda isə, siz hər bir məbləği daxil etməklə, onun Azərbaycan dilində olan qarşılığını əldə etmiş olacaqsınız. Əvvəlcə, aşağıdakı faylı endirin:

Faylı açdıqdan sonra etməli olduqlarınız:

1.Alt+F11 shortcut-ı ilə Microsoft Visual Basic for Applications pəncərəsini açın.

2. Menudan Insert >> Module seçin.

3. Sağ tərəfdə açılacaq təmiz səhifəyə aşağıdakı kodun tamamını kopyalayıb yapışdırın:

Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
    Dim Manat, Qepik, Temp
    Dim DecimalPlace, Count
    ReDim Place(9) As String
    Place(2) = " Min "
    Place(3) = " Milyon "
    Place(4) = " Milyard "
    Place(5) = " Trilyon "

    MyNumber = Trim(Str(MyNumber))
    DecimalPlace = InStr(MyNumber, ".")
    If DecimalPlace > 0 Then
        Qepik = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
                  "00", 2))
        MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
    End If
    Count = 1
    Do While MyNumber <> ""
        Temp = GetHundreds(Right(MyNumber, 3))
        If Temp <> "" Then Manat = Temp & Place(Count) & Manat
        If Len(MyNumber) > 3 Then
            MyNumber = Left(MyNumber, Len(MyNumber) - 3)
        Else
            MyNumber = ""
        End If
        Count = Count + 1
    Loop
    Select Case Manat
        Case ""
            Manat = "0 Manat"
        Case "One"
            Manat = "1 Manat"
         Case Else
            Manat = Manat & " Manat"
    End Select
    Select Case Qepik
        Case ""
            Qepik = ", 0 Qepik"
        Case "One"
            Qepik = ", 1 Qepik"
              Case Else
            Qepik = ", " & Qepik & " Qepik"
    End Select
    SpellNumber = Manat & Qepik
End Function

Function GetHundreds(ByVal MyNumber)
    Dim Result As String
    If Val(MyNumber) = 0 Then Exit Function
    MyNumber = Right("000" & MyNumber, 3)
    ' Convert the hundreds place.
    If Mid(MyNumber, 1, 1) <> "0" Then
        Result = GetDigit(Mid(MyNumber, 1, 1)) & " Yuz "
    End If
    ' Convert the tens , ones place.
    If Mid(MyNumber, 2, 1) <> "0" Then
        Result = Result & GetTens(Mid(MyNumber, 2))
    Else
        Result = Result & GetDigit(Mid(MyNumber, 3))
    End If
    GetHundreds = Result
End Function

Function GetTens(TensText)
    Dim Result As String
    Result = "" ' Null out the temporary function value.
    If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
        Select Case Val(TensText)
            Case 10: Result = "On"
            Case 11: Result = "On Bir"
            Case 12: Result = "On Iki"
            Case 13: Result = "On Uc"
            Case 14: Result = "On Dord"
            Case 15: Result = "On Bes"
            Case 16: Result = "On Alti"
            Case 17: Result = "On Yeddi"
            Case 18: Result = "On Sekkiz"
            Case 19: Result = "On Doqquz"
            Case Else
        End Select
    Else ' If value between 20-99...
        Select Case Val(Left(TensText, 1))
            Case 2: Result = "Iyirmi "
            Case 3: Result = "Otuz "
            Case 4: Result = "Qirx "
            Case 5: Result = "Elli "
            Case 6: Result = "Altmis "
            Case 7: Result = "Yetmis "
            Case 8: Result = "Seksen "
            Case 9: Result = "Doxsan "
            Case Else
        End Select
        Result = Result & GetDigit _
            (Right(TensText, 1))  ' Retrieve ones place.
    End If
    GetTens = Result
End Function

Function GetDigit(Digit)
    Select Case Val(Digit)
        Case 1: GetDigit = "Bir"
        Case 2: GetDigit = "Iki"
        Case 3: GetDigit = "Uc"
        Case 4: GetDigit = "Dord"
        Case 5: GetDigit = "Bes"
        Case 6: GetDigit = "Alti"
        Case 7: GetDigit = "Yeddi"
        Case 8: GetDigit = "Sekkiz"
        Case 9: GetDigit = "Doqquz"
        Case Else: GetDigit = ""
    End Select
End Function

Belə bir görüntümüz olmalıdır:

Vacib Qeyd: Kodu daxil etdikdən sonra Alt+Q ilə Excel səhifəmizə geri dönüb, Save As vasitəsilə Macro-Enabled Workbook (*.xlsm) olaraq yaddaşa atırıq. Əks halda, əlavə etdiyimiz kod silinəcək.

Save As etdikdən sonra, Excel faylımıza geri dönüb, SpellNumber funksiyası ilə aşağıdakı formulu yazırıq:

Digər sətirlərə kopyalayıb yapışdırdıqdan sonra, hədəfimizə çatmış oluruq. Artıq, bu formulu Ödəniş Tapşırıqlarında (Payment Order) istifadə edə bilərsiniz.

Kodun mənfi tərəfi – “ə”, “ı”, “ğ”, “ö”, “ü”, “ç” kimi hərfləri mənasız simvollara çevirməsidir. Səbəbi isə VBA-nın unicode simvollarını tanımamasıdır. O səbəblə, “Ə” yerinə “E”, “Ç” yerinə “C” yazırıq.

Uğurlar!